//Junk

script_enemy_main{

let size=0;
let shotspeed=6;
let speed=GetArgument[0];
let color=GetArgument[1];

let GRenemy=("\script\Images\Enemies\Fairy3-15.png");
let SEshotb5=("script\SoundEffects\shotb5.wav");
let SEdeath=("script\SoundEffects\enemydeath1.wav");

let miny=GetClipMinY; let maxy=GetClipMaxY; let minx=GetClipMinX; let maxx=GetClipMaxX;
let cx=GetCenterX; let cy=GetCenterY;
let startx=GetX; let starty=GetY;
let frame=0; let time=0; let animation=0;
let ani=4;
let scale=0.75;
let shots=0;
let shotcolor=0;
let oldX=0; let oldY=0;
let invincible=125;

SetSpeed(speed);
if(startx<cx){ SetAngle(0); }
if(startx>cx){ SetAngle(180); }

@Initialize{
	LoadGraphic("\script\Images\Enemies\Fairy3-15.png");
	LoadSE("script\SoundEffects\shotb5.wav");
	LoadSE("script\SoundEffects\enemydeath1.wav");
	
	SetInvincibility(30);
	SetLife(20);
	SetDamageRate(10,3); 
	SetScore(1000);
	SetShotColor(255,255,255);
}

@MainLoop{

if(GetX<=minx-32 || GetX>=maxx+32 || GetY<=miny-32 || GetY>=maxy+32 && frame>=60){ VanishEnemy; }

if((GetX>minx && GetX<maxx) && (GetY>miny && GetY<maxy)){
	SetCollisionA(GetX,GetY,32*scale);
	SetCollisionB(GetX,GetY,32*scale);
}


if(GetSpeed<1 && shots<4 && time%10==0){
let angle1=rand(0,360);
	loop(30){
		loop(8){
		let angle2=rand(0,360);
		let radius2=rand(2+(size/4),8+(size/4));
		CreateShot02(GetX+radius2*cos(angle2),GetY+radius2*sin(angle2),shotspeed,angle1,-0.06,shotspeed/2,48+color+size,10);
		}
	angle1+=360/30;
	}
PlaySE(SEshotb5);
size+=12;
shotspeed-=0.4;
shots++;
}

if(shots<4 && GetSpeed>0){
	SetSpeed(GetSpeed-0.08);
	if(GetSpeed<0){ SetSpeed(0); }
}
if(shots>=4){
	SetSpeed(GetSpeed+0.03);
	if(startx<cx){ SetAngle(GetAngle-0.7); }
	if(startx>cx){ SetAngle(GetAngle+0.7); }
}


oldX=GetX;
oldY=GetY;
frame++;
time++;
animation++;
if(animation>=ani*6){ animation=0; }
if(GetTimeOfInvincibility<25 && invincible>0){ invincible=GetTimeOfInvincibility*5; }

}

@DrawLoop{
let side=0;
	SetTexture(GRenemy);
		if(oldX<GetX || oldX>GetX){ side=128; }
		if(animation>=ani*0 && animation<ani*1){ SetGraphicRect(1,side,256,128+side); }
		if(animation>=ani*1 && animation<ani*2){ SetGraphicRect(257,side,512,128+side); }
		if(animation>=ani*2 && animation<ani*3){ SetGraphicRect(513,side,768,128+side); }
		if(animation>=ani*3 && animation<ani*4){ SetGraphicRect(769,side,1024,128+side); }
		if(animation>=ani*4 && animation<ani*5){ SetGraphicRect(513,side,768,128+side); }
		if(animation>=ani*5 && animation<ani*6){ SetGraphicRect(257,side,512,128+side); }
	SetGraphicAngle(0,0,0);
	if(oldX<GetX){ SetGraphicAngle(180,0,0); }
	SetGraphicScale(scale,scale);
	SetColor(255-invincible,255-invincible,255);
	DrawGraphic(GetX,GetY);
}

@Finalize{
if(BeVanished==false){
PlaySE(SEdeath);
	loop(8){ CreateEnemyFromFile("script\Functions\itempoint.txt",GetX+rand(-40,40),GetY+rand(-40,40),0,0,0); }
	loop(4){ CreateEnemyFromFile("script\Functions\itempower.txt",GetX+rand(-40,40),GetY+rand(-40,40),0,0,0); }
#include_function "script/Functions/PlayerTypeBonus.txt";
}
}

}