//Slowly flies down and shoots around randomly

script_enemy_main{

let GRenemy=("\script\Images\Enemies\Fairy2-12.png");
let SEshots5=("script\SoundEffects\shots5.wav");
let SEdeath=("script\SoundEffects\enemydeath1.wav");
let miny=GetClipMinY; let maxy=GetClipMaxY; let minx=GetClipMinX; let maxx=GetClipMaxX;
let cx=GetCenterX; let cy=GetCenterY;
let startx=GetX; let starty=GetY;
let frame=0; let time=0; let animation=0;
let ani=4;
let scale=0.75;
let shots=0;
let shotcolor=0; let shotspeed=0;
let oldX=0; let oldY=0;
let invincible=125;

SetSpeed(rand(4,5));
SetAngle(90+rand(-15,15));

@Initialize{
	LoadGraphic("\script\Images\Enemies\Fairy2-12.png");

	LoadSE("script\SoundEffects\shots5.wav");

	SetInvincibility(40);
	SetLife(10);
	SetDamageRate(10,3); 
	SetScore(1000);
	SetShotColor(255,255,255);
}

@MainLoop{

if(GetX<=minx-32 || GetX>=maxx+32 || GetY<=miny-32 || GetY>=maxy+32 && frame>=60){ VanishEnemy; }

if((GetX>minx && GetX<maxx) && (GetY>miny && GetY<maxy)){
SetCollisionA(GetX,GetY,32*scale);
SetCollisionB(GetX,GetY,32*scale);


if(GetCommonData("Difficulty")==1){
	if(frame%5==0 && time<240){
	let radius=rand(0,30);
	let angle=(time*3)+rand(-15,15);
		CreateShot01(GetX+radius*cos(angle),GetY+radius*sin(angle),1.25,rand(0,360),rand_int(124,126),20);
	}
	if(frame%5==0 && time<240){ PlaySE(SEshots5); }
} //Easy

//=========================================================================================================

if(GetCommonData("Difficulty")==2){
	if(frame%3==0 && time<240){
	let radius=rand(0,30);
	let angle=(time*3)+rand(-30,30);
		CreateShot01(GetX+radius*cos(angle),GetY+radius*sin(angle),1.5,rand(0,360),rand_int(124,126),20);
	}
	if(frame%5==0 && time<240){ PlaySE(SEshots5); }
} // Normal

//=========================================================================================================

if(GetCommonData("Difficulty")==3){
	if(frame%2==0){
	let radius=rand(0,30);
	let angle=(time*3)+rand(-60,60);
		CreateShot01(GetX+radius*cos(angle),GetY+radius*sin(angle),1.5,rand(0,360),rand_int(124,126),20);
	}
	if(frame%5==0){ PlaySE(SEshots5); }
} // Hard

//=========================================================================================================

if(GetCommonData("Difficulty")==4){
	if(frame<90){
		loop(3){
		let radius=rand(0,30);
		let angle=(time*3)+rand(-80,80);
		CreateShot01(GetX+radius*cos(angle),GetY+radius*sin(angle),2,rand(0,360),rand_int(124,126),20);
		}
	}
	if(frame>=90 && frame%2==0){
		let radius=rand(0,30);
		let angle=(time*3)+rand(-80,80);
		CreateShot01(GetX+radius*cos(angle),GetY+radius*sin(angle),2,rand(0,360),rand_int(124,126),20);
	}
	if(frame%5==0){ PlaySE(SEshots5); }
} // Lunatic
} // OnScreen

if(GetSpeed>0.4 && time<240){ SetSpeed(GetSpeed-0.1); }
if(time>=240 && time<400 && startx<cx){ SetAngle(GetAngle+0.9); SetSpeed(GetSpeed+0.03); }
if(time>=240 && time<400 && startx>=cx){ SetAngle(GetAngle-0.9); SetSpeed(GetSpeed+0.03); }


oldX=GetX;
oldY=GetY;
frame++;
time++;
animation++;
if(animation>=ani*6){ animation=0; }
if(GetTimeOfInvincibility<25 && invincible>0){ invincible=GetTimeOfInvincibility*5; }

}

@DrawLoop{
let side=0;
	SetTexture(GRenemy);
		if(oldX<GetX || oldX>GetX){ side=128; }
		if(animation>=ani*0 && animation<ani*1){ SetGraphicRect(1,side,256,128+side); }
		if(animation>=ani*1 && animation<ani*2){ SetGraphicRect(257,side,512,128+side); }
		if(animation>=ani*2 && animation<ani*3){ SetGraphicRect(513,side,768,128+side); }
		if(animation>=ani*3 && animation<ani*4){ SetGraphicRect(769,side,1024,128+side); }
		if(animation>=ani*4 && animation<ani*5){ SetGraphicRect(513,side,768,128+side); }
		if(animation>=ani*5 && animation<ani*6){ SetGraphicRect(257,side,512,128+side); }
	SetGraphicAngle(0,0,0);
	if(oldX<GetX){ SetGraphicAngle(180,0,0); }
	SetGraphicScale(scale,scale);
	SetColor(255-invincible,255-invincible,255);
	DrawGraphic(GetX,GetY);
}

@Finalize{
if(BeVanished==false){
PlaySE(SEdeath);
	CreateEnemyFromFile("script\Functions\itempoint.txt",GetX+rand(-40,40),GetY+rand(-25,25),0,0,0);
	CreateEnemyFromFile("script\Functions\itempower.txt",GetX+rand(-25,25),GetY+rand(-25,25),0,0,0);
	CreateEnemyFromFile("script\Functions\itemscore.txt",GetX+rand(-40,40),GetY+rand(-40,40),0,0,0);
#include_function "script/Functions/PlayerTypeBonus.txt";
}
}

}